package com.actionscriptbible
{
	import flash.display.Sprite;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.system.Capabilities;
	import flash.system.System;
	import flash.text.TextField;
	import flash.text.TextFormat;
	
	public class Example extends Sprite
	{
		protected var _traceTF:TextField;
		public static var globalTrace:Function;
		
		public function Example()
		{
			super();
			Example.globalTrace = this.trace;
			_traceTF = new TextField();
			_traceTF.defaultTextFormat = new TextFormat("_typewriter", 12, 0x0);
			_traceTF.mouseWheelEnabled = true;
      _traceTF.mouseEnabled = false;
      _traceTF.tabEnabled = false;
			_traceTF.multiline = _traceTF.wordWrap = true;
			_traceTF.addEventListener(Event.ADDED_TO_STAGE, function(event:Event):void {
			  stage.scaleMode = StageScaleMode.NO_SCALE;
			  stage.align = StageAlign.TOP_LEFT;
				stage.addEventListener(Event.RESIZE, _example_onResize);
				_example_onResize(null);
			});
			addChild(_traceTF);
			__trace("FP version:", Capabilities.version, "/", Capabilities.playerType, "/", Capabilities.isDebugger?"DEBUG":"PROD");
		}
		
		protected function _example_onResize(event:Event):void
		{
		  _traceTF.width = stage.stageWidth;
		  _traceTF.height = stage.stageHeight;
		}
		protected function trace(...rest):void
		{
			var s:String = rest.join(" ");
			_traceTF.appendText(s + "\n");
			_traceTF.scrollV = _traceTF.maxScrollV;
			__trace(s);
		}
	}
}

var __trace:Function = trace;